ansys讀入和寫出數據文件并實現多載荷步瞬態動力學求解例子

2017-03-03 by:CAE仿真在線來源:互聯網

一根半徑為0.1m長度為10m的圓柱桿直立在地面上,下端完全固定,現在記錄有0~10s之間每隔1s時候上部端點的水平作用力大小

,并按時間已經記錄在數據文件ftop.dat中。計算圓柱桿的動態響應,提取頂點在激勵方向上水平位移并存入數據文件utop.dat

中。

首先創建ftop.dat文件并存放在ansys的當前目錄下,其包含的數據內容如下:(第一列數據占3個字符寬度,第二列數據占11個

字符寬度)
1 1600
2 7000
3 15000
4 5000
5 500
6 -2000
7 -800
8 1800
9 200
10 -3400

命令流:

*create,byb,mac
finish
/clear

*dim,ftop,,10,2
*vread,ftop(1,1),ftop,dat,,jik,2,10
(f3.0,f11.0)
!按指定格式輸入數據
/prep7
et,1,beam189

sectype,1,beam,csolid,cir-sect,0
secoffset,cent
secdata,0.1
!定義梁189的截面號1
mp,ex,1,2e11
mp,nuxy,1,0.3
mp,dens,1,7800
!定義材料
/view,1,1,1,1
/ang,1
!調整圖形為等視圖顯示
k,1
k,2,,,10
k,3,1
lstr,1,2
latt,1,,1,,3,,1
!給線分配單元屬性:mat=1,type=1,方向kp=3
esize,1,0
lmesh,1

/eshape,1
!打開單元截面形狀顯示開關
eplot

dk,1,all,0
save
finish
!執行瞬態分析的循環求解過程
/solu
antype,4
!選擇瞬態分析類型
trnopt,full
!選擇瞬態完全法
nlgeom,1
!打開幾何打變形開關
outres,all,all
!求解輸入所有子步的所有結果項到結果文件中
autots,0
!關閉自動調整載荷長功能
kbc,0
!采用漸變載荷加載方式
*do,i,1,10
!執行10次循環加載
time,ftop(i,1)
!設置當前載荷步終點時間
nsubst,10,0,0
!設置當前載荷步中的子步數目

fk,2,fx,ftop(i,2)
!施加當前載荷步的終點載荷
solve
*enddo
finish

/post26
ntop=node(0,0,10)
!利用node(x,y,z)提取頂點位置上的節點編號
nsol,2,ntop,u,x,ux_top
!定義頂點位置節點的位移UX(T)記錄變量2
xvar,1
!時間記錄變量1作為X軸映射變量
plvar,2
!繪制頂節點位移UX(T)記錄變量2曲線

!創建二維數組utop(100,2)用時間序列及其對應位移填充它
*dim,utop,,100,2
!用時間序列填充數組utop(100,2)的第一列
*vfill,utop(1,1),ramp,0.1,0.1
!用位移響應ux序列填充數組utop(100,2)的第二列
vget,utop(1,2),2,0.1

!將二維數組utop(100,2)的數據寫入文件utop.dat中
*cfopen,utop,dat,,
*do,i,1,100,1
*vwrite,utop(i,1),utop(i,2)
(f3.1,' ',f15.12)
!按格式將當前行數據寫入utop.dat中
*enddo
*cfclose
*end
byb

開放分享：優質有限元技術文章,助你自學成才